Stomatal conductance​#

Stomatal conductance describes how readily gases pass between the leaf surface and the air spaces inside the leaf. PlantBiophysics calculates conductance to CO₂, Gₛ, in mol CO₂ m⁻² s⁻¹. Stomata also control water loss, which is why this process matters for both photosynthesis and leaf cooling.

Choose a model​#

The examples below run each model alone with prescribed assimilation. In a photosynthesis simulation, Fvcb calculates assimilation and stomatal conductance together, so you do not supply A.

Run the Medlyn model​#

Choose the model parameters, set the weather, and provide the leaf inputs:

using PlantBiophysics, PlantSimEngine, PlantMeteo, Dates

meteo = Atmosphere(
    T=20.0, Wind=1.0, P=101.3, Rh=0.65, duration=Hour(1),
)
stomata = Medlyn(g0=0.03, g1=12.0)
scene = CompositeModel(
    stomata;
    status=Status(A=20.0, Cₛ=400.0, Dₗ=meteo.VPD),
    environment=meteo,
)
run!(scene)
leaf = only(model_objects(scene))
leaf.status.Gₛ

The result is conductance to CO₂. If you need conductance to water vapour in the same molar units, use the conversion function:

(CO₂=leaf.status.Gₛ, H₂O=PlantBiophysics.gsc_to_gsw(leaf.status.Gₛ))

Do not directly compare Gₛ to a gas-exchange instrument's conductance without checking which gas and units the instrument reports.

Parameters​#

g0 and gs_min are separate because a fitted intercept can be negative, while the calculated conductance still needs a lower bound. The example parameter values are illustrative; see Parameter fitting to estimate them from data.

Inputs​#

The example uses air VPD for Dₗ, assuming leaf and air temperatures are equal. With an energy-balance model, leaf temperature and Dₗ are calculated together. You can inspect the model's declarations with:

(inputs=inputs(stomata), outputs=outputs(stomata))

Include leaf water stress with Tuzet​#

The Tuzet model uses leaf water potential Ψₗ (MPa) to reduce conductance as the leaf dries. You must provide that potential, either from measurements or from another model; choosing Tuzet does not itself simulate plant hydraulics.

Besides g0, g1, and gs_min, its parameters are:

g1 is dimensionless in this model; its value is not interchangeable with the Medlyn g1. Supply assimilation and surface CO₂ as before, replacing Dₗ with Ψₗ:

tuzet_scene = CompositeModel(
    Tuzet(g0=0.03, g1=12.0, Ψᵥ=-1.5, sf=2.0, Γ=30.0);
    status=Status(A=20.0, Cₛ=400.0, Ψₗ=-1.0),
    environment=meteo,
)
run!(tuzet_scene)
only(model_objects(tuzet_scene)).status.Gₛ

For positive assimilation and the same other inputs, a more negative Ψₗ reduces the water-potential response and hence conductance. The Tuzet reference gives the response function.

Prescribe a constant conductance​#

ConstantGs sets the conductance directly. For example, to use a measured value of 0.1 mol CO₂ m⁻² s⁻¹:

constant_scene = CompositeModel(ConstantGs(Gₛ=0.1); environment=meteo)
run!(constant_scene)
only(model_objects(constant_scene)).status.Gₛ

Its Gₛ parameter is the prescribed conductance; the optional g0 parameter defaults to zero and supports coupling with photosynthesis. The model needs no input variables when run alone. Prescribing measured conductance is useful when evaluating photosynthesis or energy balance independently of a stomatal model, as in the daily evaluation.

Time resolution and references​#

Stomatal-conductance models prefer an hourly timestep and accept timesteps from one minute to six hours. See Multi-rate simulation to set the simulation intervals explicitly.

The models follow Medlyn et al. (2011), Reconciling the optimal and empirical approaches to modelling stomatal conductance, and Tuzet, Perrier and Leuning (2003), A coupled model of stomatal conductance, photosynthesis and transpiration, Plant, Cell & Environment 26(7), 1097–1116.